home *** CD-ROM | disk | FTP | other *** search
/ The CICA Windows Explosion! / The CICA Windows Explosion! - Disc 2.iso / nt / emacssrc.zip / EMACSSRC.TAR / emacs-19.17 / lisp / sendmail.el < prev    next >
Lisp/Scheme  |  1993-07-23  |  30KB  |  849 lines
  1. ;;; sendmail.el --- mail sending commands for Emacs.
  2.  
  3. ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6. ;; Keywords: mail
  7.  
  8. ;; This file is part of GNU Emacs.
  9.  
  10. ;; GNU Emacs is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;; GNU General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23.  
  24. ;;; Commentary:
  25.  
  26. ;; This mode provides mail-sending facilities from within Emacs.  It is
  27. ;; documented in the Emacs user's manual.
  28.  
  29. ;;; Code:
  30.  
  31. ;;;###autoload
  32. (defvar mail-self-blind nil "\
  33. Non-nil means insert BCC to self in messages to be sent.
  34. This is done when the message is initialized,
  35. so you can remove or alter the BCC field to override the default.")
  36.  
  37. ;;;###autoload
  38. (defvar mail-interactive nil "\
  39. Non-nil means when sending a message wait for and display errors.
  40. nil means let mailer mail back a message to report errors.")
  41.  
  42. ;;;###autoload
  43. (defvar mail-yank-ignored-headers "^via:\\|^mail-from:\\|^origin:\\|^status:\\|^remailed\\|^received:\\|^message-id:\\|^summary-line:\\|^to:\\|^subject:\\|^in-reply-to:\\|^return-path:" "\
  44. Delete these headers from old message when it's inserted in a reply.")
  45.  
  46. ;; Useful to set in site-init.el
  47. ;;;###autoload
  48. (defvar send-mail-function 'sendmail-send-it "\
  49. Function to call to send the current buffer as mail.
  50. The headers are be delimited by a line which is `mail-header-separator'.")
  51.  
  52. ;;;###autoload
  53. (defvar mail-header-separator "--text follows this line--" "\
  54. *Line used to separate headers from text in messages being composed.")
  55.  
  56. ;;;###autoload
  57. (defvar mail-archive-file-name nil "\
  58. *Name of file to write all outgoing messages in, or nil for none.
  59. Do not use an rmail file here!  Instead, use its inbox file.")
  60.  
  61. (defvar mail-default-reply-to nil
  62.   "*Address to insert as default Reply-to field of outgoing messages.")
  63.  
  64. (defvar mail-alias-file nil
  65.   "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
  66. This file defines aliases to be expanded by the mailer; this is a different
  67. feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
  68. This variable has no effect unless your system uses sendmail as its mailer.")
  69.  
  70. (defvar mail-aliases t
  71.   "Alist of mail address aliases,
  72. or t meaning should be initialized from `~/.mailrc'.
  73. The alias definitions in `~/.mailrc' have this form:
  74.     alias ALIAS MEANING")
  75.  
  76. (defvar mail-yank-prefix nil
  77.   "*Prefix insert on lines of yanked message being replied to.
  78. nil means use indentation.")
  79. (defvar mail-indentation-spaces 3
  80.   "*Number of spaces to insert at the beginning of each cited line.
  81. Used by `mail-yank-original' via `mail-yank-cite'.")
  82. (defvar mail-yank-hooks '(mail-indent-citation)
  83.   "Obsolete hook for modifying a citation just inserted in the mail buffer.
  84. Each hook function can find the citation between (point) and (mark t).
  85. And each hook function should leave point and mark around the citation
  86. text as modified.
  87.  
  88. This is a normal hook, misnamed for historical reasons.
  89. It is semi-obsolete and mail agents should no longer use it.")
  90.  
  91. (defvar mail-citation-hook nil
  92.   "*Hook for modifying a citation just inserted in the mail buffer.
  93. Each hook function can find the citation between (point) and (mark t).
  94. And each hook function should leave point and mark around the citation
  95. text as modified.
  96.  
  97. If this hook is entirely empty (nil), a default action is taken
  98. instead of no action.")
  99.  
  100. (defvar mail-abbrevs-loaded nil)
  101. (defvar mail-mode-map nil)
  102.  
  103. (autoload 'build-mail-aliases "mailalias"
  104.   "Read mail aliases from `~/.mailrc' and set `mail-aliases'."
  105.   nil)
  106.  
  107. (autoload 'expand-mail-aliases "mailalias"
  108.   "Expand all mail aliases in suitable header fields found between BEG and END.
  109. Suitable header fields are `To', `Cc' and `Bcc' and their `Resent-' variants.
  110. Optional second arg EXCLUDE may be a regular expression defining text to be
  111. removed from alias expansions."
  112.   nil)
  113.  
  114. ;;;###autoload
  115. (defvar mail-signature nil
  116.   "*Text inserted at end of mail buffer when a message is initialized.
  117. If t, it means to insert the contents of the file `~/.signature'.")
  118.  
  119. (defvar mail-reply-buffer nil)
  120. (defvar mail-send-actions nil
  121.   "A list of actions to be performed upon successful sending of a message.")
  122.  
  123. (defvar mail-default-headers nil
  124.   "*A string containing header lines, to be inserted in outgoing messages.
  125. It is inserted before you edit the message,
  126. so you can edit or delete these lines.")
  127.  
  128. (defvar mail-mode-syntax-table nil
  129.   "Syntax table used while in mail mode.")
  130.  
  131. (if (null mail-mode-syntax-table)
  132.     (progn
  133.      (setq mail-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
  134.      (modify-syntax-entry ?% ". " mail-mode-syntax-table)))
  135.  
  136. (defun mail-setup (to subject in-reply-to cc replybuffer actions)
  137.   (if (eq mail-aliases t)
  138.       (progn
  139.     (setq mail-aliases nil)
  140.     (if (file-exists-p "~/.mailrc")
  141.         (build-mail-aliases))))
  142.   (setq mail-send-actions actions)
  143.   (setq mail-reply-buffer replybuffer)
  144.   (goto-char (point-min))
  145.   (insert "To: ")
  146.   (save-excursion
  147.     (if to
  148.     ;; Here removed code to extract names from within <...>
  149.     ;; on the assumption that mail-strip-quoted-names
  150.     ;; has been called and has done so.
  151.     (let ((fill-prefix "\t")
  152.           (address-start (point)))
  153.       (insert to "\n")
  154.       (fill-region-as-paragraph address-start (point-max)))
  155.       (newline))
  156.     (if cc
  157.     (let ((fill-prefix "\t")
  158.           (address-start (progn (insert "CC: ") (point))))
  159.       (insert cc "\n")
  160.       (fill-region-as-paragraph address-start (point-max))))
  161.     (if in-reply-to
  162.     (insert "In-reply-to: " in-reply-to "\n"))
  163.     (insert "Subject: " (or subject "") "\n")
  164.     (if mail-default-headers
  165.     (insert mail-default-headers))
  166.     (if mail-default-reply-to
  167.     (insert "Reply-to: " mail-default-reply-to "\n"))
  168.     (if mail-self-blind
  169.     (insert "BCC: " (user-login-name) "\n"))
  170.     (if mail-archive-file-name
  171.     (insert "FCC: " mail-archive-file-name "\n"))
  172.     (insert mail-header-separator "\n")
  173.     ;; Insert the signature.  But remember the beginning of the message.
  174.     (if to (setq to (point)))
  175.     (cond ((eq mail-signature t)
  176.        (if (file-exists-p "~/.signature")
  177.            (insert-file-contents "~/.signature")))
  178.       (mail-signature
  179.        (insert mail-signature)))
  180.     (goto-char (point-max))
  181.     (or (bolp) (newline)))
  182.   (if to (goto-char to))
  183.   (or to subject in-reply-to
  184.       (set-buffer-modified-p nil))
  185.   (run-hooks 'mail-setup-hook))
  186.  
  187. ;;;###autoload
  188. (defun mail-mode ()
  189.   "Major mode for editing mail to be sent.
  190. Like Text Mode but with these additional commands:
  191. C-c C-s  mail-send (send the message)    C-c C-c  mail-send-and-exit
  192. C-c C-f  move to a header field (and create it if there isn't):
  193.      C-c C-f C-t  move to To:    C-c C-f C-s  move to Subj:
  194.      C-c C-f C-b  move to BCC:    C-c C-f C-c  move to CC:
  195. C-c C-t  move to message text.
  196. C-c C-y  mail-yank-original (insert current message, in Rmail).
  197. C-c C-q  mail-fill-yanked-message (fill what was yanked).
  198. C-c C-v  mail-sent-via (add a sent-via field for each To or CC)."
  199.   (interactive)
  200.   (kill-all-local-variables)
  201.   (make-local-variable 'mail-reply-buffer)
  202.   (setq mail-reply-buffer nil)
  203.   (make-local-variable 'mail-send-actions)
  204.   (set-syntax-table mail-mode-syntax-table)
  205.   (use-local-map mail-mode-map)
  206.   (setq local-abbrev-table text-mode-abbrev-table)
  207.   (setq major-mode 'mail-mode)
  208.   (setq mode-name "Mail")
  209.   (setq buffer-offer-save t)
  210.   (make-local-variable 'paragraph-separate)
  211.   (make-local-variable 'paragraph-start)
  212.   (setq paragraph-start (concat "^" mail-header-separator
  213.                 "$\\|^[ \t]*[-_][-_][-_]+$\\|"
  214.                 paragraph-start))
  215.   (setq paragraph-separate (concat "^" mail-header-separator
  216.                    "$\\|^[ \t]*[-_][-_][-_]+$\\|"
  217.                    paragraph-separate))
  218.   (run-hooks 'text-mode-hook 'mail-mode-hook))
  219.  
  220. ;;; Set up keymap.
  221.  
  222. (if mail-mode-map
  223.     nil
  224.   (setq mail-mode-map (nconc (make-sparse-keymap) text-mode-map))
  225.   (define-key mail-mode-map "\C-c?" 'describe-mode)
  226.   (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
  227.   (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
  228.   (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
  229.   (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
  230.   (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
  231.   (define-key mail-mode-map "\C-c\C-t" 'mail-text)
  232.   (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
  233.   (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
  234.   (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
  235.   (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
  236.   (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
  237.   (define-key mail-mode-map "\C-c\C-s" 'mail-send))
  238.  
  239. (define-key mail-mode-map [menu-bar mail]
  240.   (cons "Mail" (make-sparse-keymap "Mail")))
  241.  
  242. (define-key mail-mode-map [menu-bar mail fill]
  243.   '("Fill Citation" . mail-fill-yanked-message))
  244.  
  245. (define-key mail-mode-map [menu-bar mail yank]
  246.   '("Cite Original" . mail-yank-original))
  247.  
  248. (define-key mail-mode-map [menu-bar mail signature]
  249.   '("Insert Signature" . mail-signature))
  250.  
  251. (define-key mail-mode-map [menu-bar mail cancel]
  252.   '("Cancel" . mail-dont-send))
  253.  
  254. (define-key mail-mode-map [menu-bar mail send-stay]
  255.   '("Send, Keep Editing" . mail-send))
  256.  
  257. (define-key mail-mode-map [menu-bar mail send]
  258.   '("Send Message" . mail-send-and-exit))
  259.  
  260. (define-key mail-mode-map [menu-bar headers]
  261.   (cons "Headers" (make-sparse-keymap "Headers")))
  262.  
  263. (define-key mail-mode-map [menu-bar headers sent-via]
  264.   '("Sent Via" . mail-sent-via))
  265.  
  266. (define-key mail-mode-map [menu-bar headers text]
  267.   '("Text" . mail-text))
  268.  
  269. (define-key mail-mode-map [menu-bar headers bcc]
  270.   '("Bcc" . mail-bcc))
  271.  
  272. (define-key mail-mode-map [menu-bar headers fcc]
  273.   '("Fcc" . mail-fcc))
  274.  
  275. (define-key mail-mode-map [menu-bar headers cc]
  276.   '("Cc" . mail-cc))
  277.  
  278. (define-key mail-mode-map [menu-bar headers subject]
  279.   '("Subject" . mail-subject))
  280.  
  281. (define-key mail-mode-map [menu-bar headers to]
  282.   '("To" . mail-to))
  283.  
  284. (defun mail-send-and-exit (arg)
  285.   "Send message like `mail-send', then, if no errors, exit from mail buffer.
  286. Prefix arg means don't delete this window."
  287.   (interactive "P")
  288.   (mail-send)
  289.   (mail-bury arg))
  290.  
  291. (defun mail-dont-send (arg)
  292.   "Don't send the message you have been editing.
  293. Prefix arg means don't delete this window."
  294.   (interactive "P")
  295.   (mail-bury arg))
  296.  
  297. (defun mail-bury (arg)
  298.   "Bury this mail buffer."
  299.   (let ((newbuf (other-buffer (current-buffer))))
  300.     (bury-buffer (current-buffer))
  301.     (if (and (cdr (assq 'dedicated (frame-parameters)))
  302.          (not (null (delq (selected-frame) (visible-frame-list)))))
  303.     (delete-frame (selected-frame))
  304.       (if (and (not arg)
  305.            (not (one-window-p))
  306.            (save-excursion
  307.          (set-buffer (window-buffer (next-window (selected-window) 'not)))
  308.          (eq major-mode 'rmail-mode)))
  309.       (delete-window)
  310.     (switch-to-buffer newbuf)))))
  311.  
  312. (defun mail-send ()
  313.   "Send the message in the current buffer.
  314. If `mail-interactive' is non-nil, wait for success indication
  315. or error messages, and inform user.
  316. Otherwise any failure is reported in a message back to
  317. the user from the mailer."
  318.   (interactive)
  319.   (if (if buffer-file-name
  320.       (y-or-n-p "Send buffer contents as mail message? ")
  321.     (or (buffer-modified-p)
  322.         (y-or-n-p "Message already sent; resend? ")))
  323.       (progn
  324.     (message "Sending...")
  325.     (run-hooks 'mail-send-hook)
  326.     (funcall send-mail-function)
  327.     ;; Now perform actions on successful sending.
  328.     (while mail-send-actions
  329.       (condition-case nil
  330.           (apply (car (car mail-send-actions))
  331.              (cdr (car mail-send-actions)))
  332.         (error))
  333.       (setq mail-send-actions (cdr mail-send-actions)))
  334.     (message "Sending...done")
  335.     ;; If buffer has no file, mark it as unmodified and delete autosave.
  336.     (if (not buffer-file-name)
  337.         (progn
  338.           (set-buffer-modified-p nil)
  339.           (delete-auto-save-file-if-necessary t))))))
  340.  
  341. (defun sendmail-send-it ()
  342.   (let ((errbuf (if mail-interactive
  343.             (generate-new-buffer " sendmail errors")
  344.           0))
  345.     (tembuf (generate-new-buffer " sendmail temp"))
  346.     (case-fold-search nil)
  347.     delimline
  348.     (mailbuf (current-buffer)))
  349.     (unwind-protect
  350.     (save-excursion
  351.       (set-buffer tembuf)
  352.       (erase-buffer)
  353.       (insert-buffer-substring mailbuf)
  354.       (goto-char (point-max))
  355.       ;; require one newline at the end.
  356.       (or (= (preceding-char) ?\n)
  357.           (insert ?\n))
  358.       ;; Change header-delimiter to be what sendmail expects.
  359.       (goto-char (point-min))
  360.       (re-search-forward
  361.         (concat "^" (regexp-quote mail-header-separator) "\n"))
  362.       (replace-match "\n")
  363.       (backward-char 1)
  364.       (setq delimline (point-marker))
  365.       (if mail-aliases
  366.           (expand-mail-aliases (point-min) delimline))
  367.       (goto-char (point-min))
  368.       ;; ignore any blank lines in the header
  369.       (while (and (re-search-forward "\n\n\n*" delimline t)
  370.               (< (point) delimline))
  371.         (replace-match "\n"))
  372.       (let ((case-fold-search t))
  373.         (goto-char (point-min))
  374.         (if (re-search-forward "^Sender:" delimline t)
  375.         (error "Sender may not be specified."))
  376.         ;; Find and handle any FCC fields.
  377.         (goto-char (point-min))
  378.         (if (re-search-forward "^FCC:" delimline t)
  379.         (mail-do-fcc delimline))
  380.         ;; If the From is different than current user, insert Sender.
  381.         (goto-char (point-min))
  382.         (and (re-search-forward "^From:"  delimline t)
  383.          (progn
  384.            (require 'mail-utils)
  385.            (not (string-equal
  386.              (mail-strip-quoted-names
  387.               (save-restriction
  388.                 (narrow-to-region (point-min) delimline)
  389.                 (mail-fetch-field "From")))
  390.              (user-login-name))))
  391.          (progn
  392.            (forward-line 1)
  393.            (insert "Sender: " (user-login-name) "\n")))
  394.         ;; "S:" is an abbreviation for "Subject:".
  395.         (goto-char (point-min))
  396.         (if (re-search-forward "^S:" delimline t)
  397.         (replace-match "Subject:"))
  398.         ;; Don't send out a blank subject line
  399.         (goto-char (point-min))
  400.         (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
  401.         (replace-match ""))
  402.         (if mail-interactive
  403.         (save-excursion
  404.           (set-buffer errbuf)
  405.           (erase-buffer))))
  406.       (apply 'call-process-region
  407.          (append (list (point-min) (point-max)
  408.                    (if (boundp 'sendmail-program)
  409.                    sendmail-program
  410.                  "/usr/lib/sendmail")
  411.                    nil errbuf nil
  412.                    "-oi" "-t")
  413.              ;; Always specify who from,
  414.              ;; since some systems have broken sendmails.
  415.              (list "-f" (user-login-name))
  416. ;;;             ;; Don't say "from root" if running under su.
  417. ;;;             (and (equal (user-real-login-name) "root")
  418. ;;;                  (list "-f" (user-login-name)))
  419.              (and mail-alias-file
  420.                   (list (concat "-oA" mail-alias-file)))
  421.              ;; These mean "report errors by mail"
  422.              ;; and "deliver in background".
  423.              (if (null mail-interactive) '("-oem" "-odb"))))
  424.       (if mail-interactive
  425.           (save-excursion
  426.         (set-buffer errbuf)
  427.         (goto-char (point-min))
  428.         (while (re-search-forward "\n\n* *" nil t)
  429.           (replace-match "; "))
  430.         (if (not (zerop (buffer-size)))
  431.             (error "Sending...failed to %s"
  432.                (buffer-substring (point-min) (point-max)))))))
  433.       (kill-buffer tembuf)
  434.       (if (bufferp errbuf)
  435.       (kill-buffer errbuf)))))
  436.  
  437. (defun mail-do-fcc (header-end)
  438.   (let (fcc-list
  439.     (rmailbuf (current-buffer))
  440.     (time (current-time))
  441.     (tembuf (generate-new-buffer " rmail output"))
  442.     (case-fold-search t))
  443.     (save-excursion
  444.       (goto-char (point-min))
  445.       (while (re-search-forward "^FCC:[ \t]*" header-end t)
  446.     (setq fcc-list (cons (buffer-substring (point)
  447.                            (progn
  448.                          (end-of-line)
  449.                          (skip-chars-backward " \t")
  450.                          (point)))
  451.                  fcc-list))
  452.     (delete-region (match-beginning 0)
  453.                (progn (forward-line 1) (point))))
  454.       (set-buffer tembuf)
  455.       (erase-buffer)
  456.       ;; This initial newline is written out if the fcc file already exists.
  457.       (insert "\nFrom " (user-login-name) " "
  458.           (current-time-string time) "\n")
  459.       ;; Insert the time zone before the year.
  460.       (forward-char -1)
  461.       (forward-word -1)
  462.       (require 'mail-utils)
  463.       (insert (mail-rfc822-time-zone time) " ")
  464.       (goto-char (point-max))
  465.       (insert-buffer-substring rmailbuf)
  466.       ;; Make sure messages are separated.
  467.       (goto-char (point-max))
  468.       (insert ?\n)
  469.       (goto-char 2)
  470.       ;; ``Quote'' "^From " as ">From "
  471.       ;;  (note that this isn't really quoting, as there is no requirement
  472.       ;;   that "^[>]+From " be quoted in the same transparent way.)
  473.       (let ((case-fold-search nil))
  474.     (while (search-forward "\nFrom " nil t)
  475.       (forward-char -5)
  476.       (insert ?>)))
  477.       (while fcc-list
  478.     (let ((buffer (get-file-buffer (car fcc-list))))
  479.       (if buffer
  480.           ;; File is present in a buffer => append to that buffer.
  481.           (let ((curbuf (current-buffer))
  482.             (beg (point-min)) (end (point-max))
  483.             (beg2 (save-excursion (goto-char (point-min))
  484.                       (forward-line 2) (point))))
  485.         (save-excursion
  486.           (set-buffer buffer)
  487.           ;; Keep the end of the accessible portion at the same place
  488.           ;; unless it is the end of the buffer.
  489.           (let ((max (if (/= (1+ (buffer-size)) (point-max))
  490.                  (point-max))))
  491.             (unwind-protect
  492.             ;; Code below lifted from rmailout.el
  493.             ;; function rmail-output-to-rmail-file:
  494.             (let ((buffer-read-only nil)
  495.                   (msg (and (boundp 'rmail-current-message)
  496.                     rmail-current-message)))
  497.               ;; If MSG is non-nil, buffer is in RMAIL mode.
  498.               (if msg
  499.                   (progn
  500.                 (rmail-maybe-set-message-counters)
  501.                 (widen)
  502.                 (narrow-to-region (point-max) (point-max))
  503.                 (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
  504.                     "From: " (user-login-name) "\n"
  505.                     "Date: " (mail-rfc822-date) "\n")
  506.                 (insert-buffer-substring curbuf beg2 end)
  507.                 (insert "\n\C-_")
  508.                 (goto-char (point-min))
  509.                 (widen)
  510.                 (search-backward "\n\^_")
  511.                 (narrow-to-region (point) (point-max))
  512.                 (rmail-count-new-messages t)
  513.                 (rmail-show-message msg)
  514.                 (setq max nil))
  515.                 ;; Output file not in rmail mode
  516.                 ;; => just insert at the end.
  517.                 (narrow-to-region (point-min) (1+ (buffer-size)))
  518.                 (goto-char (point-max))
  519.                 (insert-buffer-substring curbuf beg end)))
  520.               (if max (narrow-to-region (point-min) max))))))
  521.         ;; Else append to the file directly.
  522.         (write-region
  523.          ;; Include a blank line before if file already exists.
  524.  
  525.          (if (file-exists-p (car fcc-list)) (point-min) (1+ (point-min)))
  526.          (point-max) (car fcc-list) t)))
  527.     (setq fcc-list (cdr fcc-list))))
  528.     (kill-buffer tembuf)))
  529.  
  530. (defun mail-sent-via ()
  531.   "Make a Sent-via header line from each To or CC header line."
  532.   (interactive)
  533.   (save-excursion
  534.     (goto-char (point-min))
  535.     ;; find the header-separator
  536.     (search-forward (concat "\n" mail-header-separator "\n"))
  537.     (forward-line -1)
  538.     ;; put a marker at the end of the header
  539.     (let ((end (point-marker))
  540.       (case-fold-search t)
  541.       to-line)
  542.       (goto-char (point-min))
  543.       ;; search for the To: lines and make Sent-via: lines from them
  544.       ;; search for the next To: line
  545.       (while (re-search-forward "^\\(to\\|cc\\):" end t)
  546.     ;; Grab this line plus all its continuations, sans the `to:'.
  547.     (let ((to-line
  548.            (buffer-substring (point)
  549.                  (progn
  550.                    (if (re-search-forward "^[^ \t\n]" end t)
  551.                        (backward-char 1)
  552.                      (goto-char end))
  553.                    (point)))))
  554.       ;; Insert a copy, with altered header field name.
  555.       (insert-before-markers "Sent-via:" to-line))))))
  556.  
  557. (defun mail-to ()
  558.   "Move point to end of To-field."
  559.   (interactive)
  560.   (expand-abbrev)
  561.   (mail-position-on-field "To"))
  562.  
  563. (defun mail-subject ()
  564.   "Move point to end of Subject-field."
  565.   (interactive)
  566.   (expand-abbrev)
  567.   (mail-position-on-field "Subject"))
  568.  
  569. (defun mail-cc ()
  570.   "Move point to end of CC-field.  Create a CC field if none."
  571.   (interactive)
  572.   (expand-abbrev)
  573.   (or (mail-position-on-field "cc" t)
  574.       (progn (mail-position-on-field "to")
  575.          (insert "\nCC: "))))
  576.  
  577. (defun mail-bcc ()
  578.   "Move point to end of BCC-field.  Create a BCC field if none."
  579.   (interactive)
  580.   (expand-abbrev)
  581.   (or (mail-position-on-field "bcc" t)
  582.       (progn (mail-position-on-field "to")
  583.          (insert "\nBCC: "))))
  584.  
  585. (defun mail-fcc ()
  586.   "Add a new FCC field, with file name completion."
  587.   (interactive)
  588.   (expand-abbrev)
  589.   (or (mail-position-on-field "fcc" t)    ;Put new field after exiting FCC.
  590.       (mail-position-on-field "to"))
  591.   (insert "\nFCC: " (read-file-name "Folder carbon copy: ")))
  592.  
  593. (defun mail-position-on-field (field &optional soft)
  594.   (let (end
  595.     (case-fold-search t))
  596.     (goto-char (point-min))
  597.     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "\n"))
  598.     (setq end (match-beginning 0))
  599.     (goto-char (point-min))
  600.     (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
  601.     (progn
  602.       (re-search-forward "^[^ \t]" nil 'move)
  603.       (beginning-of-line)
  604.       (skip-chars-backward "\n")
  605.       t)
  606.       (or soft
  607.       (progn (goto-char end)
  608.          (insert field ": \n")
  609.          (skip-chars-backward "\n")))
  610.       nil)))
  611.  
  612. (defun mail-text ()
  613.   "Move point to beginning of text field."
  614.   (interactive)
  615.   (goto-char (point-min))
  616.   (search-forward (concat "\n" mail-header-separator "\n")))
  617.  
  618. (defun mail-signature (atpoint)
  619.   "Sign letter with contents of `mail-signature-file'."
  620.   (interactive "P")
  621.   (save-excursion
  622.     (or atpoint
  623.     (goto-char (point-max)))
  624.     (skip-chars-backward " \t\n")
  625.     (end-of-line)
  626.     (or atpoint
  627.     (delete-region (point) (point-max)))
  628.     (insert "\n\n")
  629.     (insert-file-contents (expand-file-name "~/.signature"))))
  630.  
  631. (defun mail-fill-yanked-message (&optional justifyp)
  632.   "Fill the paragraphs of a message yanked into this one.
  633. Numeric argument means justify as well."
  634.   (interactive "P")
  635.   (save-excursion
  636.     (goto-char (point-min))
  637.     (search-forward (concat "\n" mail-header-separator "\n") nil t)
  638.     (fill-individual-paragraphs (point)
  639.                 (point-max)
  640.                 justifyp
  641.                 t)))
  642.  
  643. (defun mail-indent-citation ()
  644.   "Modify text just inserted from a message to be cited.
  645. The inserted text should be the region.
  646. When this function returns, the region is again around the modified text.
  647.  
  648. Normally, indent each nonblank line `mail-indentation-spaces' spaces.
  649. However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
  650.   (let ((start (point)))
  651.     (mail-yank-clear-headers start (mark t))
  652.     (if (null mail-yank-prefix)
  653.     (indent-rigidly start (mark t) mail-indentation-spaces)
  654.       (save-excursion
  655.     (goto-char start)
  656.     (while (< (point) (mark t))
  657.       (insert mail-yank-prefix)
  658.       (forward-line 1))))))
  659.  
  660. (defun mail-yank-original (arg)
  661.   "Insert the message being replied to, if any (in rmail).
  662. Puts point before the text and mark after.
  663. Normally, indents each nonblank line ARG spaces (default 3).
  664. However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.
  665.  
  666. Just \\[universal-argument] as argument means don't indent, insert no prefix,
  667. and don't delete any header fields."
  668.   (interactive "P")
  669.   (if mail-reply-buffer
  670.       (let ((start (point)))
  671.     (delete-windows-on mail-reply-buffer)
  672.     (insert-buffer mail-reply-buffer)
  673.     (if (consp arg)
  674.         nil
  675.       (goto-char start)
  676.       (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
  677.                        mail-indentation-spaces)))
  678.         (if mail-citation-hook
  679.         (run-hooks 'mail-citation-hook)
  680.           (run-hooks 'mail-yank-hooks))))
  681.     ;; This is like exchange-point-and-mark, but doesn't activate the mark.
  682.     ;; It is cleaner to avoid activation, even though the command
  683.     ;; loop would deactivate the mark because we inserted text.
  684.     (goto-char (prog1 (mark t)
  685.              (set-marker (mark-marker) (point) (current-buffer))))
  686.     (if (not (eolp)) (insert ?\n)))))
  687.  
  688. (defun mail-yank-clear-headers (start end)
  689.   (save-excursion
  690.     (goto-char start)
  691.     (if (search-forward "\n\n" end t)
  692.     (save-restriction
  693.       (narrow-to-region start (point))
  694.       (goto-char start)
  695.       (while (let ((case-fold-search t))
  696.            (re-search-forward mail-yank-ignored-headers nil t))
  697.         (beginning-of-line)
  698.         (delete-region (point)
  699.                (progn (re-search-forward "\n[^ \t]")
  700.                   (forward-char -1)
  701.                   (point))))))))
  702.  
  703. ;; Put these last, to reduce chance of lossage from quitting in middle of loading the file.
  704.  
  705. ;;;###autoload
  706. (defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
  707.   "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
  708. When this function returns, the buffer `*mail*' is selected.
  709. The value is t if the message was newly initialized; otherwise, nil.
  710.  
  711. By default, the signature file `~/.signature' is inserted at the end;
  712. see the variable `mail-signature'.
  713.  
  714. \\<mail-mode-map>
  715. While editing message, type \\[mail-send-and-exit] to send the message and exit.
  716.  
  717. Various special commands starting with C-c are available in sendmail mode
  718. to move to message header fields:
  719. \\{mail-mode-map}
  720.  
  721. If `mail-self-blind' is non-nil, a BCC to yourself is inserted
  722. when the message is initialized.
  723.  
  724. If `mail-default-reply-to' is non-nil, it should be an address (a string);
  725. a Reply-to: field with that address is inserted.
  726.  
  727. If `mail-archive-file-name' is non-nil, an FCC field with that file name
  728. is inserted.
  729.  
  730. If `mail-setup-hook' is bound, its value is called with no arguments
  731. after the message is initialized.  It can add more default fields.
  732.  
  733. When calling from a program, the second through fifth arguments
  734.  TO, SUBJECT, IN-REPLY-TO and CC specify if non-nil
  735.  the initial contents of those header fields.
  736.  These arguments should not have final newlines.
  737. The sixth argument REPLYBUFFER is a buffer whose contents
  738.  should be yanked if the user types C-c C-y.
  739. The seventh argument ACTIONS is a list of actions to take
  740.  if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
  741.  when the message is sent, we apply FUNCTION to ARGS.
  742.  This is how Rmail arranges to mark messages `answered'."
  743.   (interactive "P")
  744. ;;; This is commented out because I found it was confusing in practice.
  745. ;;; It is easy enough to rename *mail* by hand with rename-buffer
  746. ;;; if you want to have multiple mail buffers.
  747. ;;; And then you can control which messages to save. --rms.
  748. ;;;  (let ((index 1)
  749. ;;;    buffer)
  750. ;;;    ;; If requested, look for a mail buffer that is modified and go to it.
  751. ;;;    (if noerase
  752. ;;;    (progn
  753. ;;;      (while (and (setq buffer
  754. ;;;                (get-buffer (if (= 1 index) "*mail*"
  755. ;;;                      (format "*mail*<%d>" index))))
  756. ;;;              (not (buffer-modified-p buffer)))
  757. ;;;        (setq index (1+ index)))
  758. ;;;      (if buffer (switch-to-buffer buffer)
  759. ;;;        ;; If none exists, start a new message.
  760. ;;;        ;; This will never re-use an existing unmodified mail buffer
  761. ;;;        ;; (since index is not 1 anymore).  Perhaps it should.
  762. ;;;        (setq noerase nil))))
  763. ;;;    ;; Unless we found a modified message and are happy, start a new message.
  764. ;;;    (if (not noerase)
  765. ;;;    (progn
  766. ;;;      ;; Look for existing unmodified mail buffer.
  767. ;;;      (while (and (setq buffer
  768. ;;;                (get-buffer (if (= 1 index) "*mail*"
  769. ;;;                      (format "*mail*<%d>" index))))
  770. ;;;              (buffer-modified-p buffer))
  771. ;;;        (setq index (1+ index)))
  772. ;;;      ;; If none, make a new one.
  773. ;;;      (or buffer
  774. ;;;          (setq buffer (generate-new-buffer "*mail*")))
  775. ;;;      ;; Go there and initialize it.
  776. ;;;      (switch-to-buffer buffer)
  777. ;;;      (erase-buffer)
  778. ;;;          (setq default-directory (expand-file-name "~/"))
  779. ;;;          (auto-save-mode auto-save-default)
  780. ;;;          (mail-mode)
  781. ;;;          (mail-setup to subject in-reply-to cc replybuffer actions)
  782. ;;;      (if (and buffer-auto-save-file-name
  783. ;;;           (file-exists-p buffer-auto-save-file-name))
  784. ;;;          (message "Auto save file for draft message exists; consider M-x mail-recover"))
  785. ;;;          t))
  786.   (switch-to-buffer "*mail*")
  787.   (setq default-directory (expand-file-name "~/"))
  788.   (auto-save-mode auto-save-default)
  789.   (mail-mode)
  790.   (let (initialized)
  791.     (and (not noerase)
  792.      (or (not (buffer-modified-p))
  793.          (y-or-n-p "Unsent message being composed; erase it? "))
  794.      (progn (erase-buffer)
  795.         (mail-setup to subject in-reply-to cc replybuffer actions)
  796.         (setq initialized t)))
  797.     (if (and buffer-auto-save-file-name
  798.          (file-exists-p buffer-auto-save-file-name))
  799.     (message "Auto save file for draft message exists; consider M-x mail-recover"))
  800.     initialized))
  801.  
  802. (defun mail-recover ()
  803.   "Reread contents of current buffer from its last auto-save file."
  804.   (interactive)
  805.   (let ((file-name (make-auto-save-file-name)))
  806.     (cond ((save-window-excursion
  807.          (if (not (eq system-type 'vax-vms))
  808.          (with-output-to-temp-buffer "*Directory*"
  809.            (buffer-disable-undo standard-output)
  810.            (call-process "ls" nil standard-output nil "-l" file-name)))
  811.          (yes-or-no-p (format "Recover auto save file %s? " file-name)))
  812.        (let ((buffer-read-only nil))
  813.          (erase-buffer)
  814.          (insert-file-contents file-name nil)))
  815.       (t (error "mail-recover cancelled.")))))
  816.  
  817. ;;;###autoload
  818. (defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  819.   "Like `mail' command, but display mail buffer in another window."
  820.   (interactive "P")
  821.   (let ((pop-up-windows t))
  822.     (pop-to-buffer "*mail*"))
  823.   (mail noerase to subject in-reply-to cc replybuffer sendactions))
  824.  
  825. ;;;###autoload
  826. (defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  827.   "Like `mail' command, but display mail buffer in another frame."
  828.   (interactive "P")
  829.   (let ((pop-up-frames t))
  830.     (pop-to-buffer "*mail*"))
  831.   (mail noerase to subject in-reply-to cc replybuffer sendactions))
  832.  
  833.  
  834. ;;;###autoload
  835. (define-key ctl-x-map "m" 'mail)
  836.  
  837. ;;;###autoload
  838. (define-key ctl-x-4-map "m" 'mail-other-window)
  839.  
  840. ;;;###autoload
  841. (define-key ctl-x-5-map "m" 'mail-other-frame)
  842.  
  843.  
  844. ;;; Do not add anything but external entries on this page.
  845.  
  846. (provide 'sendmail)
  847.  
  848. ;;; sendmail.el ends here
  849.